Интегриране с външни програми

4 май 2023

Административни неща

Project guide: https://vim-fmi.bg/guides/projects
- Няма нужда да бързате, ще говорим още за проектите и ще има още идеи

Преговор

По-екзотични регекси

Преговор

По-екзотични регекси
Цветове и шаренийки

Преговор

По-екзотични регекси
Цветове и шаренийки
:TOhtml

Преговор

По-екзотични регекси
Цветове и шаренийки
:TOhtml
Spellchecking

Преговор

По-екзотични регекси
Цветове и шаренийки
:TOhtml
Spellchecking
Низови функции с регекси: matchstr, substitute

Преговор

По-екзотични регекси
Цветове и шаренийки
:TOhtml
Spellchecking
Низови функции с регекси: matchstr, substitute
search-фамилията от функции

Input

let answer = input("How do you feel today? ")
redraw

if answer =~? 'good\|okay\|alright'
  echomsg "Cool."
else
  echomsg "Yeah whatever"
endif

Input: допълнителни параметри

Дефолтна стойност
Completion (:help command-completion)

let new_name = input("Rename file: ", expand('%'), 'file')
redraw
echomsg $"Preview: call rename('{expand('%')}', '{new_name}')"

Input: варианти

let answer = inputlist([
      \   "Коя от тези функции работи върху буфера?",
      \   "1) matchstr()",
      \   "2) searchpairpos()",
      \   "3) substitute()",
      \ ])
redraw

if answer == 2
  call sound_playevent('dialog-information')
  echohl String | echomsg "✅" | echohl None
else
  call sound_playevent('dialog-warning')
  echohl ErrorMsg | echomsg "❌" | echohl None
endif

Input: пароли

let cc = inputsecret("Enter your credit card, don't worry about it")

Странично: Vim може да криптира файлове:

:help encryption
:help :X
:help 'cryptmethod'

Confirm: Y/N?

if confirm("Download spell file?", "&Yes\n&No", 2) == 1
  echomsg "No."
endif

Redir

Малко хакаво, ама не е за сефте:

redir => output
  silent digraphs
redir END

let umlaut_digraph = matchstr(output, '..\ze ü')
redraw
echomsg "Digraph for ü is: '" .. umlaut_digraph .. "'"

redir => <var> ще създаде променлива с това име и ще напълни output-а в нея.

Redir

Малко хакаво, ама не е за сефте:

redir => output
  silent digraphs
redir END

let umlaut_digraph = matchstr(output, '..\ze ü')
redraw
echomsg "Digraph for ü is: '" .. umlaut_digraph .. "'"

redir => <var> ще създаде променлива с това име и ще напълни output-а в нея.
silent командата спира output-а на вътрешната команда, но не за redir. Без silent, би напечатало output-а освен да го сложи в output.

Redir

Малко хакаво, ама не е за сефте:

redir => output
  silent digraphs
redir END

let umlaut_digraph = matchstr(output, '..\ze ü')
redraw
echomsg "Digraph for ü is: '" .. umlaut_digraph .. "'"

redir => <var> ще създаде променлива с това име и ще напълни output-а в нея.
silent командата спира output-а на вътрешната команда, но не за redir. Без silent, би напечатало output-а освен да го сложи в output.
Дребна досада: silent! преди команда скрива грешки, но те пак се появяват в output-а на redir

Redir

Има варианти за файл и за регистри

:redi[r][!] > {file} -- записва файл
:redi[r][!] >> {file} -- append-ва във файл
:redi[r] @{a-zA-Z*+"}> -- във регистър
:redi[r] => {var} -- append-ва в променлива

Вместо redir: execute()

Днешно време има по-удобен вариант, :help execute():

let output = execute('digraphs', 'silent')

let umlaut_digraph = matchstr(output, '..\ze ü')
redraw
echomsg "Digraph for ü is: '" .. umlaut_digraph .. "'"

Този път, може да подадем и silent! и ще глътне грешките.

Вместо redir: execute()

Днешно време има по-удобен вариант, :help execute():

let output = execute('digraphs', 'silent')

let umlaut_digraph = matchstr(output, '..\ze ü')
redraw
echomsg "Digraph for ü is: '" .. umlaut_digraph .. "'"

Този път, може да подадем и silent! и ще глътне грешките.
Може да се викне с няколко поредни команди в списък: execute([cmd1, cmd2])

Вместо redir: execute()

Днешно време има по-удобен вариант, :help execute():

let output = execute('digraphs', 'silent')

let umlaut_digraph = matchstr(output, '..\ze ü')
redraw
echomsg "Digraph for ü is: '" .. umlaut_digraph .. "'"

Този път, може да подадем и silent! и ще глътне грешките.
Може да се викне с няколко поредни команди в списък: execute([cmd1, cmd2])
Впрочем, digraph_getlist(v:true) ще ни даде всички digraphs по доста по-прост начин. Вижте :help digraph_get( и скролнете надолу.

Lambda функции

:help lambda

Можем да си дефинираме "анонимна функция" или "ламбда". Тези двете са горе-долу еквивалентни:

function Add1(x, y)
  return a:x + a:y
endfunction

let Add2 = { x, y -> x + y }

echomsg Add1(3, 4)
echomsg Add2(3, 4)
" 7
" 7

Ламбда функция с един аргумент е { input -> ... }, с нула е { -> ... }.

Lambda функции

Ламбдите могат да имат само един expression. Не можем да дефинираме променливи или да извикваме команди, макар че в случай на голяма нужда, винаги има execute().

Но удобството им е предимно за функции като map(), filter(), reduce().

Map, filter, reduce

let numbers = [1, 2, 3, 4, 5]
let doubled_numbers = map(copy(numbers), { i, n -> n * 2 })
" => [2, 4, 6, 8, 10]
let odd_numbers = filter(copy(numbers), { i, n -> n % 2 == 1 })
" => [1, 3, 5]
let numbers_sum = reduce(copy(numbers), { sum, n -> sum + n }, 0)
" => 15